initial commit with unmodified qt5-based bootloader flash utility source from the MLA

qt5_src/Bootloader/Bootloader.pro

@@ -0,0 +1,71 @@
+TARGET = "HIDBootloader"
+TEMPLATE = app
+QT += sql
+QT += widgets
+QMAKE_CXXFLAGS_RELEASE = -Os
+INCLUDEPATH += ../
+SOURCES += \
+    Settings.cpp \
+    MainWindow.cpp \
+    main.cpp \
+    DeviceData.cpp \
+    Device.cpp \
+    Comm.cpp \
+    ImportExportHex.cpp
+HEADERS += \
+    Settings.h \
+    MainWindow.h \
+    DeviceData.h \
+    Device.h \
+    Comm.h \
+    ImportExportHex.h
+
+
+FORMS += MainWindow.ui \
+    Settings.ui
+RESOURCES += resources.qrc
+OTHER_FILES += windows.rc
+
+#-------------------------------------------------
+# Add the correct HIDAPI library according to what
+# OS is being used
+#-------------------------------------------------
+win32: LIBS += -L../HIDAPI/windows
+macx: LIBS += -L../HIDAPI/mac
+unix: !macx: LIBS += -L../HIDAPI/linux
+LIBS += -lHIDAPI
+
+#-------------------------------------------------
+# Make sure to add the required libraries or
+# frameoworks for the hidapi to work depending on
+# what OS is being used
+#-------------------------------------------------
+macx: LIBS += -framework CoreFoundation -framework IOkit
+win32: LIBS += -lSetupAPI
+unix: !macx: LIBS += -lusb-1.0
+
+#-------------------------------------------------
+# Make sure output directory for object file and
+# executable is in the correct subdirectory
+#-------------------------------------------------
+macx {
+    DESTDIR = mac
+    OBJECTS_DIR = mac
+    MOC_DIR = mac
+    UI_DIR = mac
+    RCC_DIR = mac
+}
+unix: !macx {
+    DESTDIR = linux
+    OBJECTS_DIR = linux
+    MOC_DIR = linux
+    UI_DIR = linux
+    RCC_DIR = linux
+}
+win32 {
+    DESTDIR = windows
+    OBJECTS_DIR = windows
+    MOC_DIR = windows
+    UI_DIR = windows
+    RCC_DIR = windows
+}